startup.d

misiekgrabo · 2010-12-02, 15:07

Witam, mam problem który od jakiegoś czasu się pojawia, ja myślę że to skrypty, dlatego temat napisałem TU. Nie mogę włożyć swoich postaci i monster'ów do gry na waypointach. Wiem że to się robi na startup.d lecz nie znalazłem takiego tutorialu. Robię nowego func voida itp. otwieram klamrę w pliku startup.d robię tam co tam chcę, oto cały skrypt:

func void STARTUP_SKALAMOD ()
{

   Wld_InsertNpc    (Scavenger,          "SCIERWOJAD_1");
   Wld_InsertNpc    (Scavenger,          "SCIERWOJAD_2");
   Wld_InsertNpc    (Scavenger,          "SCIERWOJAD_3");
   Wld_InsertNpc    (Scavenger,          "SCIERWOJAD_4");
   Wld_InsertNpc    (Scavenger,          "SCIERWOJAD_5");
   Wld_InsertNpc    (Scavenger,          "SCIERWOJAD_6");
   Wld_InsertNpc    (Scavenger,          "SCIERWOJAD_7");
   Wld_InsertNpc    (Molerat,          "KRETOSZCZUR_ALEMBIK");
   Wld_InsertNpc    (BAU_20012_Gan,       "FARM_GAN_STAY_POCZATEK");
   Wld_InsertNpc    (BAU_20001_Wlasciciel,       "FARM_WLASCICIEL_STAY_POCZATEK");
   Wld_InsertNpc    (BAU_20002_Sekwan,       "FARM_ISC_9");
   Wld_InsertNpc    (BAU_20003_Brahma,       "FARM_ZBIERANIE_BRAHMA_1");
   Wld_InsertNpc    (KDW_20004_Kertulus,       "KERTULUS_ALCHEMY");
   Wld_InsertNpc    (KDF_20005_Archibald,       "MONASTERY_ARCHIBALD_KILL");
   Wld_InsertNpc    (NONE_20006_Michal,       "MICHAL");
   Wld_InsertNpc    (NONE_20007_Kacper,       "KACPER");
   Wld_InsertNpc    (BDT_20008_Bandyta,       "BANDYTA_DOL_PILNOWAC");
   Wld_InsertNpc    (BDT_20009_Bandyta,       "BANDYTA_SRODEK_STOLEK");
   Wld_InsertNpc    (BDT_20010_Bandyta,       "BANDYTA_GORA_1");
   Wld_InsertNpc    (BDT_20011_SzefBandytow,   "SZEF_BANDYTOW_DUMNY");

};

Waypointy w świecie mam zrobione, postacie także, przy reparsowaniu skryptów nie wyskakuje ŻADEN błąd, potem robię Udpate, robię paczkę z modem z plikami OU.BIN, GOTHIC.DAT i moim worldem. Plik .ini mam także dobry z ustawioną paczką z modem i tym światem, lecz...postaci nie ma. Robię je kodami, wszystkie postacie układają się we własną rutynę, ale ja chcę zrobić moda, a tu trzeba kodami przyzywać...I tutaj zaczyna się pytanie: Co mam jeszcze dodać?

Proszę o odpowiedź zaawansowanych skrypterów i takich którzy JUŻ stworzyli moda z własnymi postaciami, a nie o odpowiedź amatorów...

RafalBudzis · #1 2010-12-02, 15:37(Ostatnia zmiana: 2010-12-02, 15:49)

świat nazywa się SKALAMOD.ZEN ??

EDIT
zerknąłem po poście Jastrzębia i dobrze mówi xD

na końcu powinno być

Kod: [Zaznacz]

   B_InitMonsterAttitudes ();
   B_InitGuildAttitudes();

ale nic innego nie widzę

ja moduje G1 moze jastrząb moduje G2 i dlatego

@misiekgrabo pisz w nazwie tematu o jakiego gothic`a ci chodzi ;)

Jastrzab · #2 2010-12-02, 15:38

Moim zdaniem pod ostatnim

Kod: [Zaznacz]

Wld_InsertNpc (BDT_20011_SzefBandytow, "SZEF_BANDYTOW_DUMNY");powinieneś dopisać:

Kod: [Zaznacz]

ENTERED_nazwa świata = TRUE;
CurrentLevel = nazwa świata_ZEN;
};

A poza tym zapomniałeś tego pod twoim skryptem:

Kod: [Zaznacz]

FUNC VOID INIT_nazwa świata ()
{

    B_InitMonsterAttitudes ();
	B_InitGuildAttitudes();
	B_InitNpcGlobals ();
	
	B_ENTER_nazwa świata ();
	
};

Spróbuj, powinno być ok.

misiekgrabo · #3 2010-12-02, 16:42

Chodziło mi o G2NK, ale żaden z was nie miał racji, trzeba było napisać dwa nowe skrypty. Już sobie poradziłem, tylko że jest kolejny błąd chcę zrobić martwą postać - Archibalda(mniszka, maga ognia), tylko jak to zrobić? Trzeba zapewne też pogrzebać w startup.d. Powtarzam - chodzi mi o G2NK.

RafalBudzis · #4 2010-12-02, 16:51

Kod: [Zaznacz]

	var C_NPC dead; dead = Hlp_GetNpc(instance NPC);
	Npc_ChangeAttribute	(dead, ATR_HITPOINTS, -dead.attribute[ATR_HITPOINTS_MAX]);

misiekgrabo · #5 2010-12-02, 17:01

A gdzie to włożyć? I czy to jest do G2NK?

RafalBudzis · #6 2010-12-02, 17:06

Cytat: misiekgrabo link=topic=12139.msg121569#msg121569#msg121569#msg121569 date=1291305680

A gdzie to włożyć? I czy to jest do G2NK?

do G1 i G2 tak samo ten wypadek wrzucasz do Startup.d tak jak wspomniałeś ;)

misiekgrabo · #7 2010-12-03, 07:24

Dzięki, ci RafalBudzis, moja postać którą chciałem zabić jest martwa, tylko że jak za bardzo się od niej oddalimy to znika. Co mam zrobić żeby WCALE nie znikła, tylko jak się wszystko od niej weźmie?

inż. Avallach · #8 2010-12-03, 15:25

Daj jej w ekwipunku ItMi_Stuff_OldCoin_02 (nie pytaj, magia

).

misiekgrabo · #9 2010-12-03, 15:58(Ostatnia zmiana: 2010-12-03, 23:23)

"DZIĘKS"!! Moja wersja Beta moda wyjdzie dzisiaj, pierwsza oficjalna wersja, może jutro, może pojutrze, a może 6 grudnia na Mikołajki

Dzięki ci, Avallach!

Ej, mam jeszcze jeden problem - Jak zrobić w dialogu koniec całej gry???

jendrzejs · **#10** 2010-12-03, 16:56

Cytuj

ExitGame();

Na koniec dialogu to dodaj.

misiekgrabo · **#11** 2010-12-03, 17:52

I mam jeszcze jedno pytanie: Robiłem dialogi na Easy Dialog Maker 3.2, zmieniałem rutynę innej postaci, mam tak:

B_ExchangeRoutine (BAU_20012_Gan, "Rtn_Gan_20012");

Moje pytanie brzmi: Co w tym skrypcie jest źle?

RafalBudzis · **#12** 2010-12-03, 18:00

prześlij skrypt postaci Gan

misiekgrabo · **#13** 2010-12-03, 18:06

instance BAU_20012_Gan (Npc_Default)
{
   // ------ NSC ------
   name       = "Gan";
   guild       = GIL_BAU;
   id          = 20012;
   voice       = 6;
   flags = 0;                              //NPC_FLAG_IMMORTAL oder 0
   npctype      = NPCTYPE_MAIN;

   // ------ Attribute ------

   attribute[ATR_STRENGTH]       = 30;
   attribute[ATR_DEXTERITY]       = 20;
   attribute[ATR_MANA_MAX]       = 0;
   attribute[ATR_MANA]          = 0;
   attribute[ATR_HITPOINTS_MAX]      = 100;
   attribute[ATR_HITPOINTS]       = 100;                                                   //setzt Attribute und LEVEL entsprechend dem angegebenen Kapitel (1-6)

   // ------ Kampf-Taktik ------
   fight_tactic      = FAI_HUMAN_COWARD;   // MASTER / STRONG / NORMAL / COWARD

   // ------ Equippte Waffen ------                                                   //Munition wird automatisch generiert, darf aber angegeben werden
   EquipItem         (self, ItMw_1h_Bau_Axe);

   // ------ Inventory ------
   B_CreateAmbientInv    (self);
   CreateInvItems       (self, ItPl_Berryred, 4);
   CreateInvItems       (self, ItPl_Carrot, 1);
   CreateInvItems       (self, ItFo_Addon_Orange, 2);
   CreateInvItems       (self, ItPl_Cucumber, 5);

   // ------ visuals ------                                                         //Muss NACH Attributen kommen, weil in B_SetNpcVisual die Breite abh. v. STR skaliert wird
   B_SetNpcVisual       (self, MALE, "Hum_Head_Bald", Face_N_NormalBart_Dexter, BodyTex_N, ITAR_BAU_M);
   Mdl_SetModelFatness   (self, 0);
   Mdl_ApplyOverlayMds   (self, "Humans_Tired.mds"); // Tired / Militia / Mage / Arrogance / Relaxed

   // ------ NSC-relevante Talente vergeben ------
   B_GiveNpcTalents (self);

   // ------ Kampf-Talente ------                                                      //Der enthaltene B_AddFightSkill setzt Talent-Ani abhängig von TrefferChance% - alle Kampftalente werden gleichhoch gesetzt
   B_SetFightSkills (self, 10); //Grenzen für Talent-Level liegen bei 30 und 60

   // ------ TA anmelden ------
   daily_routine       = Rtn_Start_20012;
};

FUNC VOID Rtn_Start_20012 ()
{
   TA_Stand_WP      (07,00,21,00,"FARM_GAN_STAY_POCZATEK");
   TA_Stand_WP       (21,00,07,00,"FARM_GAN_STAY_POCZATEK");
};

FUNC VOID Rtn_Gan_20012 ()
{
   TA_Rake_FP      (05,00,07,00,"FARM_ZBIERANIE_GAN");
   TA_Rake_FP      (07,00,09,00,"FARM_ZBIERANIE_GAN_1");
   TA_Rake_FP      (09,00,10,00,"FARM_ZBIERANIE_GAN");
   TA_Rake_FP      (10,00,11,00,"FARM_ZBIERANIE_GAN_1");
   TA_Sit_Bench      (11,00,13,00,"FARM_SIEDZENIE_GAN");
   TA_Rake_FP      (13,00,14,00,"FARM_ZBIERANIE_GAN");
   TA_Rake_FP      (14,00,15,00,"FARM_ZBIERANIE_GAN_1");
   TA_Rake_FP      (15,00,16,00,"FARM_ZBIERANIE_GAN");
   TA_Rake_FP      (16,00,17,00,"FARM_ZBIERANIE_GAN_1");
   TA_Sleep      (17,00,05,00,"FARM_SPAC_GAN");

};

Zucklov · **#14** 2010-12-27, 16:23

Zamiast
B_ExchangeRoutine (BAU_20012_Gan, "Rtn_Gan_20012");
Powinno być:
B_ExchangeRoutine (BAU_20012_Gan, "GAN");

misiekgrabo

RafalBudzis

Jastrzab

misiekgrabo

RafalBudzis

misiekgrabo

RafalBudzis

misiekgrabo

inż. Avallach

misiekgrabo

jendrzejs

misiekgrabo

RafalBudzis

misiekgrabo

Zucklov