Problem z npc

[Darkmodders]

Witam

Mam problem ostatnio z tym błędem:


Próbowałem go naprawić na kilka sposobów. Zmieniałem instance npc ale to nic nie dawało. Numery instance są wolne także nie kolidują z żadnym innym. Nie wiem co tu może być nie tak.

Tu podrzucam skrypt postaci i dialog:

Kod: [Zaznacz]

instance NON_19078_Raul (Npc_Default)
{
//-------- primary data --------

name = "Raul";
Npctype = Npctype_Main;
guild = GIL_NONE;     
level = 19;

voice = 13;
id = 19078;

//-------- abilities --------

attribute[ATR_STRENGTH] = 65;
attribute[ATR_DEXTERITY] = 40;
attribute[ATR_MANA_MAX] = 0;
attribute[ATR_MANA] = 0;
attribute[ATR_HITPOINTS_MAX] = 200;
attribute[ATR_HITPOINTS] = 200;

//-------- visuals --------
// animations
Mdl_SetVisual (self,"HUMANS.MDS");
Mdl_ApplyOverlayMds (self,"Humans_Militia.mds");
// body mesh, head mesh, hairmesh, face-tex, hair-tex, skin
Mdl_SetVisualBody (self,"hum_body_Naked0",0, 1,"Hum_Head_Fighter", 35,  2, GRD_ARMOR_M);

B_Scale (self);
Mdl_SetModelFatness (self, 0);

fight_tactic = FAI_HUMAN_STRONG;

//-------- Talente --------                                   

Npc_SetTalentSkill (self, NPC_TALENT_CROSSBOW,1);
Npc_SetTalentSkill (self, NPC_TALENT_2H,1);
Npc_SetTalentSkill (self, NPC_TALENT_1H,1);

//-------- inventory --------
                                   
CreateInvItems (self, ItKeLockpick,3);
CreateInvItems(self, ItMiNugget, 40);
CreateInvItems (self, ItFoRice,8);
CreateInvItems (self, ItFoBooze, 7);
CreateInvItems (self, ItLsTorch, 2);
CreateInvItems (self, ItFo_Potion_Health_01, 3);
CreateInvItem (self, ItMi_Stuff_Plate_01);
CreateInvItem (self, ItMi_Stuff_Cup_01);
CreateInvItem (self, ItFoMutton);
CreateInvItem (self, ItAt_Teeth_01);
  EquipItem (self, ItMw_1H_Sword_02);
EquipItem (self, ItRw_Crossbow_01);
CreateInvItems (self, ItAmBolt, 20);

//-------------Daily Routine-------------
daily_routine = Rtn_start_19078;
};

FUNC VOID Rtn_start_19078 ()
{
TA_SitCampfire (00,05,14,05,"MINE_34");
TA_Smalltalk     (14,05,17,20,"HUM2");
TA_Guard            (17,20,19,50,"MINE_20");
TA_SitCampfire      (19,50,00,05,"MINE_34");
};

Kod: [Zaznacz]

// ************************************************************
//      EXIT
// ************************************************************

INSTANCE DIA_Raul_EXIT (C_INFO)
{
npc = NON_19078_Raul;
nr = 999;
condition = DIA_Raul_EXIT_Condition;
information = DIA_Raul_EXIT_Info;
permanent = 1;
description = DIALOG_ENDE;
};                       

FUNC INT DIA_Raul_EXIT_Condition()
{
return 1;
};

FUNC VOID DIA_Raul_EXIT_Info()
{

   
AI_StopProcessInfos (self);
};

// ************************************************************
// Hallo
// ************************************************************

INSTANCE DIA_Raul_Hello (C_INFO)
{
npc = NON_19078_Raul;
nr = 1;
condition = DIA_Raul_Hello_Condition;
information = DIA_Raul_Hello_Info;
permanent = 0;
description = "To twoja kopalnia?";
};                       

FUNC INT DIA_Raul_Hello_Condition()
{
return 1;
};

FUNC VOID DIA_Raul_Hello_Info()
{
AI_Output (other, self,"DIA_Raul_Hello_15_00"); //To twoja kopalnia?
AI_Output (self, other,"DIA_Raul_Hello_12_01"); //Nie. Kopalnia należy do Ukkosa.
AI_Output (self, other,"DIA_Raul_Hello_12_02"); //Ja tu tylko objąłem dowódźtwo nad kopaczami.
};
// ************************************************************
// Lorenzo
// ************************************************************

INSTANCE DIA_Raul_Lorenzo (C_INFO)
{
npc = NON_19078_Raul;
nr = 1;
condition = DIA_Raul_Lorenzo_Condition;
information = DIA_Raul_Lorenzo_Info;
permanent = 0;
description = "Przysyła mnie Lorenzo.";
};                       

FUNC INT DIA_Raul_Lorenzo_Condition()
{
if (log_straznik == TRUE)
{
return 1;
};
};
FUNC VOID DIA_Raul_Lorenzo_Info()
{
AI_Output (other, self,"DIA_Raul_lorenzo_15_00"); //Przysyła mnie Lorenzo. Mam zarzegnać wasze problemy.
AI_Output (self, other,"DIA_Raul_Lorenzo_12_01"); //Nareszcie. Myślałem że sam będe musiał się już wszystkim zając.
AI_Output (other, self,"DIA_Raul_Lorenzo_12_02"); //Czym mam się zająć?
AI_Output (self, other,"DIA_Raul_Lorenzo_12_03"); //Ostatnio mamy duże problemy z pełzaczami.
AI_Output (self, other,"DIA_Raul_Lorenzo_12_04"); //Te cholery zerzarły nam z tuzin kopaczy i zajeły kolejne szyby.
AI_Output (self, other,"DIA_Raul_Lorenzo_12_05"); //Pozbądź się ich i znajdź ich leże.
AI_Output (other, self,"DIA_Raul_Lorenzo_12_06"); //Które szyby zajeły?
AI_Output (self, other,"DIA_Raul_Lorenzo_12_07"); //Trzy szyby w tym jeden główny skąd wychodzą tuzinami.
AI_Output (self, other,"DIA_Raul_Lorenzo_12_08"); //Gdybyśmy nie zamkneli szybu w pore to pełzacze zajełyby całą kopalnie.
AI_Output (other, self,"DIA_Raul_Lorenzo_12_09"); //No dobra. Jak się dostane do tego szybu?
AI_Output (self, other,"DIA_Raul_Lorenzo_12_10"); //W prosty sposób. Idź do Rachima i powiedz mu że masz pozwolenie ode mnie i żeby dał ci klucz do zamkniętego szybu.
AI_Output (other, self,"DIA_Raul_Lorenzo_12_11"); //W takim razie biore się do roboty.

Log_CreateTopic (Pelzacze, LOG_MISSION);
Log_SetTopicStatus (Pelzacze,   LOG_RUNNING);
B_LogEntry (Pelzacze, "Najważniejszym problemem kopalni są pełzacze, które zajeły główny szyb i trzy szyby polączone z tym głównym. Powiedział mi żebym znalazł ich leże i żebym ich wytępił. Za trudne to chyba nie będzie. Tak sądze.");


};
// ************************************************************
// Szyb
// ************************************************************

INSTANCE DIA_Raul_Szyb (C_INFO)
{
npc = NON_19078_Raul;
nr = 1;
condition = DIA_Raul_Szyb_Condition;
information = DIA_Raul_Szyb_Info;
permanent = 0;
description = "Pozbyłem się pełzaczy.";
};                       

FUNC INT DIA_Raul_Szyb_Condition()
{
     if  Npc_KnowsInfo(hero, DIA_Raul_Lorenzo)
     && (Npc_IsDead(MinecrawlerQueen))
&& (Npc_IsDead(Minecrawler_01))
&& (Npc_IsDead(Minecrawler_02))
&& (Npc_Isdead(Minecrawler_03))
&& (Npc_IsDead(Minecrawler_04))
&& (Npc_IsDead(Minecrawler_05))
&& (Npc_IsDead(Minecrawler_06))
&& (Npc_IsDead(Minecrawler_07))
&& (Npc_IsDead(Minecrawler_08))
&& (Npc_IsDead(Minecrawler_09))
&& (Npc_IsDead(Minecrawler_10))
&& (Npc_IsDead(Minecrawler_11))
&& (Npc_IsDead(Minecrawler_12))
&& (Npc_IsDead(Minecrawler_13))
&& (Npc_IsDead(Minecrawler_14))
&& (Npc_IsDead(Minecrawler_15))
&& (Npc_IsDead(Minecrawler_16))
&& (Npc_IsDead(Minecrawler_17))
&& (Npc_IsDead(Minecrawler_18))
 
{
return 1;
};
};
FUNC VOID DIA_Raul_Szyb_Info()
{
AI_Output (other, self,"DIA_Raul_Szyb_15_00"); //Pozbyłem się pełazczy.
AI_Output (self, other,"DIA_Raul_Szyb_12_01"); //Świetnie. Teraz będziemy mieli spokój.
AI_Output (self, other,"DIA_Raul_Szyb_12_02"); //Spisałeś się na medal.
B_GiveInvItems  (self,other,ItmiNugget,350);
B_GiveInvItems  (self,other,ItFoBeer,10);
B_GiveInvItems      (self,other,ItFo_Potion_Health_01,7);

Log_SetTopicStatus (Pelzacze,   LOG_SUCCESS);
B_LogEntry (Pelzacze, "Jeden problem mniej.");


};
// ************************************************************
// Magazynier
// ************************************************************

INSTANCE DIA_Raul_Magazynier (C_INFO)
{
npc = NON_19078_Raul;
nr = 1;
condition = DIA_Raul_Magazynier_Condition;
information = DIA_Raul_Magazynier_Info;
permanent = 0;
description = "Coś was jeszcze gnębi?";
};                       

FUNC INT DIA_Raul_Magazynier_Condition()
{
    if Npc_KnowsInfo(hero, DIA_Raul_Szyb)
{
return 1;
};
};
FUNC VOID DIA_Raul_Magazynier_Info()
{
AI_Output (other, self,"DIA_Raul_Magazynier_15_00"); //Coś was jeszcze gnębi?
AI_Output (self, other,"DIA_Raul_Magazynier_12_01"); //Tak szajka rabusiów.
AI_Output (self, other,"DIA_Raul_Magazynier_12_02"); //Ostatnio znika coraz większy urobek z kopalni.
AI_Output (self, other,"DIA_Raul_Magazynier_12_03"); //Ta szajka musi mieć kogoś w kopalni kto kradnie tą rude.
AI_Output (self, other,"DIA_Raul_Magazynier_12_04"); //Znajdź tego złodzieja i jego bande i pozbądź się ich.


Log_CreateTopic (Magazynier, LOG_MISSION);
Log_SetTopicStatus (Magazynier,     LOG_RUNNING);
B_LogEntry (Magazynier, "Ostatnio z kopalni znika dość spory urobek rudy. Raul chce żebym odnalazł tą szajke i odebrał im skradzioną rude. Popytam ludzi w kopalni. Może oni coś wiedzą.");


};
// ************************************************************
// Szajka
// ************************************************************

INSTANCE DIA_Raul_Szajka (C_INFO)
{
npc = NON_19078_Raul;
nr = 1;
condition = DIA_Raul_Szajka_Condition;
information = DIA_Raul_Szajka_Info;
permanent = 0;
description = "Pozbyłem się tej szajki.";
};                       

FUNC INT DIA_Raul_Szajka_Condition()
{
    if Npc_KnowsInfo(hero, DIA_Bandit_Arbeit)
&& (Npc_HasItems(other, ItMi_Pocket_Nugget)>=6)
{
return 1;
};
};
FUNC VOID DIA_Raul_Szajka_Info()
{
AI_Output (other, self,"DIA_Raul_Szajka_15_00"); //Pozbyłem się tej szajki i odzyskałem skradzioną rude.
B_GiveInvItems  (other,self,ItMi_Pocket_Nugget,6);
AI_Output (self, other,"DIA_Raul_Szajka_12_01"); //Kto był za to odpowiedzialny?
AI_Output (other, self,"DIA_Raul_Szajka_12_02"); //Magazynier. Nakrył go Radmar jak kradł worki z rudą i przemycał ją na zewnątrz.
AI_Output (self, other,"DIA_Raul_Szajka_12_03"); //Dobra robota. Przynajmniej teraz będziemy mogli pracować spokojnie.
AI_Output (other, self,"DIA_Raul_Szajka_12_04"); //A co z magazynierem?
AI_Output (self, other,"DIA_Raul_Szajka_12_05"); //Wymierze mu odpowiednią kare. Oto się nie martw.

Log_SetTopicStatus (Magazynier,     LOG_SUCCESS);
B_LogEntry (Magazynier, "Oddałem Raulowi skradzione worki z rudą.");


};

// ************************************************************
// NORMAL
// ************************************************************

INSTANCE DIA_Raul_Normal (C_INFO)
{
npc = NON_19078_Raul;
nr = 1;
condition = DIA_Raul_Normal_Condition;
information = DIA_Raul_Normal_Info;
permanent = 0;
description = "Potrzebujecie jeszcze pomocy?";
};                       

FUNC INT DIA_Raul_Normal_Condition()
{
    if Npc_KnowsInfo(hero, DIA_Raul_Szajka)
{
return 1;
};
};
FUNC VOID DIA_Raul_Normal_Info()
{
AI_Output (other, self,"DIA_Raul_Normal_15_00"); //Potrzebujecie jeszcze pomocy?
AI_Output (self, other,"DIA_Raul_Normal_12_01"); //Już nie. Rozwikłałeś wszystkie nasze problemy.
AI_Output (self, other,"DIA_Raul_Normal_12_02"); //Możesz teraz wracać do Lorenzo.


B_LogEntry (Kopalnia, "Pozbyłem się wszystkich problemów kopalni. Teraz moge wreszcie zdać raport Lorenzowi.");



};


[bgb]

Unkown identifier  NON_10078_Raul , a w skrypcie masz  NON_19078_Raul

[Adanos]

Poruszaj temat: http://themodders.org/index.php?topic=15239.0 oraz sprawdź, czy plik NPC ma rozszerzenie *.d.

[Darkmodders]

Unkown identifier  NON_10078_Raul , a w skrypcie masz  NON_19078_Raul

Mam 19078 gdyż zmieniłem z 10078. Na screenie jest jeszcze stare instance.

Poruszaj temat: http://themodders.org/index.php?topic=15239.0 oraz sprawdź, czy plik NPC ma rozszerzenie *.d.

Ma rozszerzenie .d. Kopiowałem je z istniejących postaci.
Post połączony: 2014-10-18, 17:56Mam pytanie odnośnie tego problemu. Dodałem tą postać i wiele innych do takich folderów, które zadeklarowałem w gothic.scr

Kod: [Zaznacz]

STORY\MOD_NPC\ROGUE_NPC\QUENTIN_ROGUE\*.D
STORY\MOD_NPC\ROGUE_NPC\LORENZO_ROGUE\*.D
STORY\MOD_NPC\ROGUE_NPC\SURFACE_ROGUE\*.D
STORY\MOD_NPC\CAMP_NPC\*.D
STORY\MOD_NPC\CASTLE_NPC\*.D
STORY\MOD_NPC\SURFACE_NPC\*.D
STORY\MOD_NPC\OTHER_NPC\*.D
STORY\MOD_NPC\NEW_NPC\*.D
Czy to może stwarzać problem?

[Adanos]

Tak, jeśli w złym miejscu to dodałeś. Wydaje mi się, że nie musisz dopisywać nowych NPC do gothic.src. Parser chyba czyta podkatalogi...

[Darkmodders]

Wrzuce te postacie do folderu oryginalnego NPC i sprawdze czy będzie działać.
Post połączony: 2014-10-18, 18:10Działa . Okazało się że te foldery wadziły. Dzięki wam wszystkim za pomoc. Propsy sie wam należą