Problem z dialogami

[Xitros]

Witam. Wlasnie zrobilem nowa postac i dodalem jej dialogi.
Podchodze do postaci i mnie zaczepia, jednak nic nie widac napisow i odrazu wyskakuja opcje dialogowe: "koniec", "kim jestes" oraz "co tu robisz". Gdy klikam na jedna z tych opcji zaden z postaci nic nie mowi, nawet nie wyskakuja napisy i sa kolejne opcje dialogowe. (Jak bysmy rozmawiali z "insert CH", zadnych napisow). Oraz nie widac polskich znakow.

Spoiler

Skrypty dialogow:

//*********************************************************************
//   Info EXIT
//*********************************************************************
INSTANCE DIA_MIL_2200_MOD_Talon_EXIT   (C_INFO)
{
   npc         = MIL_2200_MOD_Talon;
   nr          = 999;
   condition   = DIA_MIL_2200_MOD_Talon_EXIT_Condition;
   information = DIA_MIL_2200_MOD_Talon_EXIT_Info;
   permanent   = TRUE;
   description = DIALOG_ENDE;
};

FUNC INT DIA_MIL_2200_MOD_Talon_EXIT_Condition()
{
   return TRUE;
};

FUNC VOID DIA_MIL_2200_MOD_Talon_EXIT_Info()
{
   AI_StopProcessInfos (self);
};

// ************************************************************
//                           Hallo
// ************************************************************
instance DIA_MIL_2200_MOD_Talon_Hello (C_INFO)
{
   npc         = MIL_2200_MOD_Talon;
   nr         = 1;
   condition   = DIA_MIL_2200_MOD_Talon_Hello_Condition;
   information   = DIA_MIL_2200_MOD_Talon_Hello_Info;
   permanent   = FALSE;
   important   = TRUE;
};                       
FUNC INT DIA_MIL_2200_MOD_Talon_Hello_Condition()
{   
   return TRUE;
};
FUNC VOID DIA_MIL_2200_MOD_Talon_Hello_Info()
{   
   AI_Output (self ,other, "DIA_MIL_2200_MOD_Talon_Hello_60_00"); //Zatrzymaj się, kim jestes?
   AI_Output (other, self, "DIA_MIL_2200_MOD_Talon_Hello_15_01"); //Nieważne kim jestem. Obudziłam się w jaskini, a mój dom został spalony, a rodzina została zamordowana.
   AI_Output (self ,other, "DIA_MIL_2200_MOD_Talon_Hello_60_02"); //Przepraszam, nie wiedziałem.
   AI_Output (self ,other, "DIA_MIL_2200_MOD_Talon_Hello_60_03"); //Jeśli mogłbym Ci jakąś pomóc... wystarczy powiedzieć.
};

//*********************************************************************
//   Info
//*********************************************************************
INSTANCE DIA_MIL_2200_MOD_Talon_info   (C_INFO)
{
   npc         = MIL_2200_MOD_Talon;
   nr          = 2;
   condition   = DIA_MIL_2200_MOD_Talon_info_Condition;
   information = DIA_MIL_2200_MOD_Talon_info_Info;
   permanent   = FALSE;
   description = "Kim jesteś?";
};

FUNC INT DIA_MIL_2200_MOD_Talon_info_Condition()
{
   if (Npc_Knowsinfo (other,DIA_MIL_2200_MOD_Talon_Hello))
   {   
      return TRUE;
   };
};

FUNC VOID DIA_MIL_2200_MOD_Talon_info_Info()
{
   AI_Output (other,self ,"DIA_MIL_2200_MOD_Talon_info_15_00"); //Kim jesteś?
   AI_Output (self ,other,"DIA_MIL_2200_MOD_Talon_info_60_01"); //Jestem byłym skazańcem z kolonii, za barierą byłem strażnikiem.
   AI_Output (self ,other,"DIA_MIL_2200_MOD_Talon_info_60_02"); //Wiedziałem, że prędzej czy później byli skazańcy będą uważani za bandytów.
   AI_Output (self ,other,"DIA_MIL_2200_MOD_Talon_info_60_03"); //Dlatego poszedłem odrazu do Khorinis i zobaczyłem się z Andre, dowódcą straży miejskiej.
   AI_Output (self ,other,"DIA_MIL_2200_MOD_Talon_info_60_04"); //Zostałem strażnikiem i w końcu Andre dowiedział się, że jestem byłym skazańcem.
   
   Info_ClearChoices (DIA_MIL_2200_MOD_Talon_info);
   Info_AddChoice (DIA_MIL_2200_MOD_Talon_info,"Zwolnij, chyba się rozgadałeś.",DIA_MIL_2200_MOD_Talon_info_Talon);
   Info_AddChoice (DIA_MIL_2200_MOD_Talon_info,"Kontynuuj...",DIA_MIL_2200_MOD_Talon_Continue);
};

FUNC VOID DIA_MIL_2200_MOD_Talon_Continue ()
{
   AI_Output (self ,other,"DIA_MIL_2200_MOD_Talon_Continue_60_00"); //Potem sędzia przyszedł z paladynami i na placu by mi ścieli głowe.
   AI_Output (self ,other,"DIA_MIL_2200_MOD_Talon_continue_60_01"); //Nagle pojawił się Lord Andre z Lordem Hagenem i powiedzieli, że sędzia nie ma prawa ściąć jednego z jego ludzi.
   AI_Output (self ,other,"DIA_MIL_2200_MOD_Talon_Continue_60_02"); //Lord Andre opowiedział o tym jak ciężko pracowałem, o tym co zrobiłem, oraz jaki jestem zdolny.
   AI_Output (self ,other,"DIA_MIL_2200_MOD_Talon_Continue_60_03"); //Potem powiedziałem, że się zmieniłem i nie jestem taki jak kiedyś.
   AI_Output (self ,other,"DIA_MIL_2200_MOD_Talon_Continue_60_03"); //Lord Hagen powiedział, że uzyskam ułaskawienie, ale moje prawa zostaną zmniejszone.
   AI_Output (self ,other,"DIA_MIL_2200_MOD_Talon_Continue_60_03"); //Zgodziłęm się, chciałem być strażnikiem tak jak w górniczej dolinie, po za tym nie miałem innego wyboru.
   AI_Output (self ,other,"DIA_MIL_2200_MOD_Talon_Continue_60_03"); //Od tamtej pory wykonuje zlecenia Andre i Hagena.
};

FUNC VOID DIA_MIL_2200_MOD_Talon_info_Talon ()
{
   AI_Output (other ,self,"DIA_MIL_2200_MOD_Talon_info_Talon_15_00"); //Zwolnij, chyba się rozgadałeś
   AI_Output (self ,other,"DIA_MIL_2200_MOD_Talon_info_Talon_60_01"); //Masz racje, przepraszam.
};

//*********************************************************************
//   Info 2
//*********************************************************************
INSTANCE DIA_MIL_2200_MOD_Talon_info2   (C_INFO)
{
   npc         = MIL_2200_MOD_Talon;
   nr          = 3;
   condition   = DIA_MIL_2200_MOD_Talon_info2_Condition;
   information = DIA_MIL_2200_MOD_Talon_info2_Info;
   permanent   = FALSE;
   description = "Co tu robisz?";
};

FUNC INT DIA_MIL_2200_MOD_Talon_info2_Condition()
{
   if (Npc_Knowsinfo (other,DIA_MIL_2200_MOD_Talon_Hello))
   {   
      return TRUE;
   };
};

FUNC VOID DIA_MIL_2200_MOD_Talon_info2_Info()
{
   AI_Output (other,self ,"DIA_MIL_2200_MOD_Talon_info2_15_00"); //Co tu robisz?
   AI_Output (self ,other,"DIA_MIL_2200_MOD_Talon_info2_60_01"); //Wykonuje zlecenie dla Lorda Andre.
   AI_Output (self ,other,"DIA_MIL_2200_MOD_Talon_info2_60_02"); //Mam się zająć bandytami.
};

//*********************************************************************
//   Info 3
//*********************************************************************
INSTANCE DIA_MIL_2200_MOD_Talon_info3   (C_INFO)
{
   npc         = MIL_2200_MOD_Talon;
   nr          = 4;
   condition   = DIA_MIL_2200_MOD_Talon_info3_Condition;
   information = DIA_MIL_2200_MOD_Talon_info3_Info;
   permanent   = FALSE;
   description = "Możesz mnie zaprowadzić do miasta?";
};

FUNC INT DIA_MIL_2200_MOD_Talon_info3_Condition()
{
   if (Npc_Knowsinfo (other,DIA_MIL_2200_MOD_Talon_info2))
   {   
      return TRUE;
   };
};

FUNC VOID DIA_MIL_2200_MOD_Talon_info3_Info()
{
   AI_Output (other,self ,"DIA_MIL_2200_MOD_Talon_info3_15_00"); //Możesz mnie zaprowadzić do miasta?
   AI_Output (self ,other,"DIA_MIL_2200_MOD_Talon_info3_60_01"); //Dobrze. Ale muszę się zająć bandytami. Jeśli mi pomożesz, to będę mogł Cie zaprowadzić.

   Log_CreateTopic (TOPIC_Talon, LOG_MISSION);
   Log_SetTopicStatus (TOPIC_Talon, LOG_RUNNING);
   B_LogEntry (TOPIC_Talon,"Talon zaprowadzi mnie do miasta, jeśli rozprawi się z bandytami.");
};

//*********************************************************************
//   zadanie
//*********************************************************************
INSTANCE DIA_MIL_2200_MOD_Talon_zadanie   (C_INFO)
{
   npc         = MIL_2200_MOD_Talon;
   nr          = 5;
   condition   = DIA_MIL_2200_MOD_Talon_zadanie_Condition;
   information = DIA_MIL_2200_MOD_Talon_zadanie_Info;
   permanent   = FALSE;
   description = "Pomogę Ci";
};

FUNC INT DIA_MIL_2200_MOD_Talon_zadanie_Condition()
{
   if (Npc_Knowsinfo (other,DIA_MIL_2200_MOD_Talon_info3))
   {   
      return TRUE;
   };
};

FUNC VOID DIA_MIL_2200_MOD_Talon_zadanie_Info()
{
   AI_Output (other,self ,"DIA_MIL_2200_MOD_Talon_zadanie_15_00"); //Pomogę Ci.
   AI_Output (self ,other,"DIA_MIL_2200_MOD_Talon_zadanie_60_01"); //Zajmij się łucznikiem, ja pójdę przodem.

   Log_CreateTopic (TOPIC_Talon, LOG_MISSION);
   Log_SetTopicStatus (TOPIC_Talon, LOG_RUNNING);
   B_LogEntry (TOPIC_Talon,"Talon powiedział, żebym trzymała się z boku.");
   Npc_ExchangeRoutine (self, "Bandit");
   self.aivar[AIV_PARTYMEMBER] = TRUE;
   AI_StopProcessInfos (self);
};

//*********************************************************************
//   Koniec zadania
//*********************************************************************
INSTANCE DIA_MIL_2200_MOD_Talon_konieczadania   (C_INFO)
{
   npc         = MIL_2200_MOD_Talon;
   nr          = 6;
   condition   = DIA_MIL_2200_MOD_Talon_konieczadania_Condition;
   information = DIA_MIL_2200_MOD_Talon_konieczadania_Info;
   permanent   = FALSE;
   important   = TRUE;
};

FUNC INT DIA_MIL_2200_MOD_Talon_konieczadania_Condition()
{
   if (Npc_Knowsinfo (other,DIA_MIL_2200_MOD_Talon_zadanie))
   {   
      return TRUE;
   };
};

FUNC VOID DIA_MIL_2200_MOD_Talon_konieczadania_Info()
{
   AI_Output (other,self ,"DIA_MIL_2200_MOD_Talon_konieczadania_15_00"); //Udało się, przeszukaj bandytów, może znajdziesz coś wartościowego.
   AI_Output (self ,other,"DIA_MIL_2200_MOD_Talon_konieczadania_60_01"); //Jeśli będziesz gotowa, możemy iść do miasta.

   
   Log_SetTopicStatus (TOPIC_Talon, LOG_SUCCESS);
   B_LogEntry (TOPIC_Talon,"Udało się nam powstrzymać bandytów.");
   Npc_ExchangeRoutine (self, "Bandit2");
   self.aivar[AIV_PARTYMEMBER] = FALSE;
   AI_StopProcessInfos (self);
};

//*********************************************************************
//   Farma Akila   
//*********************************************************************
INSTANCE DIA_MIL_2200_MOD_Talon_Akil   (C_INFO)
{
   npc         = MIL_2200_MOD_Talon;
   nr          = 7;
   condition   = DIA_MIL_2200_MOD_Talon_Akil_Condition;
   information = DIA_MIL_2200_MOD_Talon_Akil_Info;
   permanent   = FALSE;
   description = "Chodźmy";
};

FUNC INT DIA_MIL_2200_MOD_Talon_Akil_Condition()
{
   if (Npc_Knowsinfo (other,DIA_MIL_2200_MOD_Talon_konieczadania))
   {   
      return TRUE;
   };
};

FUNC VOID DIA_MIL_2200_MOD_Talon_Akil_Info()
{
   AI_Output (other,self ,"DIA_MIL_2200_MOD_Talon_Akil_15_00"); //Chodźmy.

   Npc_ExchangeRoutine (self, "Farma");
   self.aivar[AIV_PARTYMEMBER] = TRUE;
   AI_StopProcessInfos (self);
};

//*********************************************************************
//   Akil
//*********************************************************************
INSTANCE DIA_MIL_2200_MOD_Talon_farma   (C_INFO)
{
   npc         = MIL_2200_MOD_Talon;
   nr          = 8;
   condition   = DIA_MIL_2200_MOD_Talon_farma_Condition;
   information = DIA_MIL_2200_MOD_Talon_farma_Info;
   permanent   = FALSE;
   important   = TRUE;
};

FUNC INT DIA_MIL_2200_MOD_Talon_farma_Condition()
{
   if (Npc_Knowsinfo (other,DIA_MIL_2200_MOD_Talon_Akil))
   {   
      return TRUE;
   };
};

FUNC VOID DIA_MIL_2200_MOD_Talon_farma_Info()
{
   AI_Output (self, other,"DIA_MIL_2200_MOD_Talon_farma_60_00"); //Wygląda na to, że farmer ma kłopoty, pomóżmy mu i ruszamy w droge.

   Npc_ExchangeRoutine (self, "FarmaAkil");
   AI_StopProcessInfos (self);
};

//*********************************************************************
//   Khorinis
//*********************************************************************
INSTANCE DIA_MIL_2200_MOD_Talon_khorinis   (C_INFO)
{
   npc         = MIL_2200_MOD_Talon;
   nr          = 10;
   condition   = DIA_MIL_2200_MOD_Talon_khorinis_Condition;
   information = DIA_MIL_2200_MOD_Talon_khorinis_Info;
   permanent   = FALSE;
   important   = TRUE;
};

FUNC INT DIA_MIL_2200_MOD_Talon_khorinis_Condition()
{
   if (Npc_Knowsinfo (other,DIA_MIL_2200_MOD_Talon_help))
   {   
      return TRUE;
   };
};

FUNC VOID DIA_MIL_2200_MOD_Talon_khorinis_Info()
{
   AI_Output (self, other,"DIA_MIL_2200_MOD_Talon_khorinis_60_00"); //No to jesteśmy.
   B_GivePlayerXP   (XP_50);
   AI_Output (self, other,"DIA_MIL_2200_MOD_Talon_khorinis_60_01"); //Weź ten glejt, dzięki niemu wejdziesz do miasta.
   CreateInvItems (self,ItWr_Passierschein, 1);
   B_GiveInvItems (self, other, ItWr_Passierschein, 1);
   AI_Output (other, self,"DIA_MIL_2200_MOD_Talon_khorinis_15_02"); //Dzięki za pomoc.
   AI_Output (other, self,"DIA_MIL_2200_MOD_Talon_khorinis_15_03"); //Nie wiem jak Ci się odwdzięczyć.
   AI_Output (self, other,"DIA_MIL_2200_MOD_Talon_khorinis_60_04"); //Nie musisz.

   Log_SetTopicStatus (TOPIC_TalonAndre, LOG_RUNNING);
   B_LogEntry (TOPIC_TalonAndre,"Muszę pochwalić Talona przed Andre, za uratowanie mi życia. Tylko tak mogę się odwdzięczyć.");
   Npc_ExchangeRoutine (self, "Khorinis");
   self.aivar[AIV_PARTYMEMBER] = FALSE;
   AI_StopProcessInfos (self);
};

//*********************************************************************
//   Talon
//*********************************************************************
INSTANCE DIA_Andre_Talon   (C_INFO)
{
   npc         = Mil_311_Andre;
   nr          = 100;
   condition   = DIA_Andre_Talon_Condition;
   information = DIA_Andre_Talon_Info;
   permanent   = FALSE;
   description   = "Możemy porozmawiać o Talonie?";
};

FUNC INT DIA_Andre_Talon_Condition()
{
   if (Npc_Knowsinfo (other,DIA_MIL_2200_MOD_Talon_khorinis))
   {   
      return TRUE;
   };
};

FUNC VOID DIA_Andre_Talon_Info()
{
   AI_Output (other, self ,"DIA_MIL_2200_MOD_Talon_konieczadania_15_00"); //Możemy porozmawiać o Talonie?
   AI_Output (self , other,"DIA_MIL_2200_MOD_Talon_konieczadania_61_01"); //Oczywiście, o co chodzi?
   AI_Output (other, self ,"DIA_MIL_2200_MOD_Talon_konieczadania_15_02"); //Talon uratował mi życie przed wieloma bandytami.
   AI_Output (self, other ,"DIA_MIL_2200_MOD_Talon_konieczadania_61_03"); //Naprawdę? a masz na to jakiś dowód?
   AI_Output (other, self ,"DIA_MIL_2200_MOD_Talon_konieczadania_15_04"); //Ich ciała leża nadal na moście w drodze do tawerny, jeśli mi nie wieżysz możesz sprawdzić.
   AI_Output (self, other ,"DIA_MIL_2200_MOD_Talon_konieczadania_61_05"); //No dobrze, wierzę Ci. Talon jest jednak inny niż myślałem.
   AI_Output (self, other ,"DIA_MIL_2200_MOD_Talon_konieczadania_61_06"); //Jeśli możesz, poinformuj go o awansie.
   AI_Output (other, self ,"DIA_MIL_2200_MOD_Talon_konieczadania_15_07"); //Napewno się ucieszy.
   
   B_LogEntry (TOPIC_TalonAndre,"Pochwaliłam Talona, przed Andre, muszę mu przekazać, że dostaje awans.");
   AI_StopProcessInfos (self);
};

Skrypt postaci:

instance MIL_2200_MOD_Talon (Npc_Default)
{
   // ------ NSC ------
   name       = "Talon";
   guild       = GIL_MIL;
   id          = 2200;
   voice       = 14;
   flags       = NPC_FLAG_IMMORTAL;      //NPC_FLAG_IMMORTAL oder 0
   npctype      = NPCTYPE_MAIN;
   
   // ------ Attribute ------
   B_SetAttributesToChapter (self, 4);                                                   //setzt Attribute und LEVEL entsprechend dem angegebenen Kapitel (1-6)
   
   // ------ Kampf-Taktik ------
   fight_tactic      = FAI_HUMAN_STRONG;   // MASTER / STRONG / COWARD
   
   // ------ Equippte Waffen ------                                                   //Munition wird automatisch generiert, darf aber angegeben werden
   EquipItem         (self, ItMw_Schwert4);
   
   // ------ Inventory ------
   B_CreateAmbientInv    (self);
      
   // ------ visuals ------                                                         //Muss NACH Attributen kommen, weil in B_SetNpcVisual die Breite abh. v. STR skaliert wird
   B_SetNpcVisual       (self, MALE, "Hum_Head_FatBald", Face_N_Normal14, BodyTex_N, ITAR_mil_h);   
   Mdl_SetModelFatness   (self, 2);
   Mdl_ApplyOverlayMds   (self, "HumanS_Militia.mds"); // Tired / Militia / Mage / Arrogance / Relaxed

   // ------ NSC-relevante Talente vergeben ------
   B_GiveNpcTalents (self);
   
   // ------ Kampf-Talente ------                                                      //Der enthaltene B_AddFightSkill setzt Talent-Ani abhängig von TrefferChance% - alle Kampftalente werden gleichhoch gesetzt
   B_SetFightSkills (self, 50); //Grenzen für Talent-Level liegen bei 30 und 60i

   // ------ TA anmelden ------
   daily_routine       = Rtn_Start_2200;
};

FUNC VOID Rtn_Start_2200 ()
{
   TA_Stand_Guarding         (09,00,21,00,"NW_MOD_TALON");
    TA_Stand_Guarding         (21,00,09,00,"NW_MOD_TALON");
};

FUNC VOID Rtn_Bandit_2200 ()
{
   TA_Guide_Player         (09,00,21,00,"NW_MOD_TALON_BANDIT");
    TA_Guide_Player         (21,00,09,00,"NW_MOD_TALON_BANDIT");
};

FUNC VOID Rtn_Bandit2_2200 ()
{
   TA_Stand_Guarding         (09,00,21,00,"NW_MOD_TALON_BANDIT");
    TA_Stand_Guarding         (21,00,09,00,"NW_MOD_TALON_BANDIT");
};

FUNC VOID Rtn_Farma_2200 ()
{
   TA_Guide_Player         (09,00,21,00,"NW_CITY_TO_FARM2_11");
    TA_Guide_Player         (21,00,09,00,"NW_CITY_TO_FARM2_11");
};

FUNC VOID Rtn_FarmaAkil_2200 ()
{
   TA_Stand_ArmsCrossed      (09,00,21,00,"NW_MOD_TALON_AKIL");
    TA_Stand_ArmsCrossed      (21,00,09,00,"NW_MOD_TALON_AKIL");
};

FUNC VOID Rtn_City_2200 ()
{
   TA_Guide_Player         (09,00,21,00,"CITY2");
    TA_Guide_Player         (21,00,09,00,"CITY2");
};

FUNC VOID Rtn_Khorinis_2200 ()
{
   TA_Stand_Guarding         (09,00,21,00,"CITY2");
    TA_Stand_Guarding         (21,00,09,00,"CITY2");
};

FUNC VOID Rtn_miasto_2200 ()
{
   TA_Stand_Guarding         (09,00,21,00,"CITY_TALON");
    TA_Stand_Guarding         (21,00,09,00,"CITY_TALON");
};

@EDIT
Zapomnialem dodac skrypty. 

//*********************************************************************
//   Talon
//*********************************************************************
INSTANCE DIA_MIL_2200_MOD_Talon_help   (C_INFO)
{
   npc         = MIL_2200_MOD_Talon;
   nr          = 9;
   condition   = DIA_MIL_2200_MOD_Talon_help_Condition;
   information = DIA_MIL_2200_MOD_Talon_help_Info;
   permanent   = FALSE;
   description = "Możemy już iść";
};

FUNC INT DIA_MIL_2200_MOD_Talon_help_Condition()
{
   if (Npc_Knowsinfo (other,DIA_Akil_NachKampf))
   && Hlp_StrCmp   (Npc_GetNearestWP(self),"NW_MOD_TALON_FARMA")
   {   
      return TRUE;
   };
};

FUNC VOID DIA_MIL_2200_MOD_Talon_help_Info()
{
   AI_Output (other, self,"DIA_MIL_2200_MOD_Talon_help_15_00"); //Możemy już iść.
   AI_Output (self, other,"DIA_MIL_2200_MOD_Talon_help_60_01"); //Ruszajmy.

   Npc_ExchangeRoutine (self, "City");
   AI_StopProcessInfos (self);
};

//*********************************************************************
//   Talon
//*********************************************************************
INSTANCE DIA_MIL_2200_MOD_Talon_andre   (C_INFO)
{
   npc         = MIL_2200_MOD_Talon;
   nr          = 11;
   condition   = DIA_MIL_2200_MOD_Talon_andre_Condition;
   information = DIA_MIL_2200_MOD_Talon_andre_Info;
   permanent   = FALSE;
   description   = "Dostałeś awans";
};

FUNC INT DIA_MIL_2200_MOD_Talon_andre_Condition()
{
   if (Npc_Knowsinfo (other,DIA_Andre_Talon))
   {   
      return TRUE;
   };
};

FUNC VOID DIA_MIL_2200_MOD_Talon_andre_Info()
{
   AI_Output (other, self,"DIA_MIL_2200_MOD_Talon_khorinis_15_00"); //Dostałeś awans.
   B_GivePlayerXP   (XP_50);
   AI_Output (self, other,"DIA_MIL_2200_MOD_Talon_khorinis_60_01"); //Nie rozumiem...
   AI_Output (other, self,"DIA_MIL_2200_MOD_Talon_khorinis_15_02"); //Rozmawiałam z Lordem Andre, kazał mi przekazać, że dostajesz awans.
   AI_Output (self, other,"DIA_MIL_2200_MOD_Talon_khorinis_60_03"); //To świetnie, wreszcie będę mógł wejść do górnego miasta.
   AI_Output (self, other,"DIA_MIL_2200_MOD_Talon_khorinis_60_04"); //Przyjmij te pare sztuk złota w ramach podziękowania.
   CreateInvItems (self,itmi_gold, 20);
   B_GiveInvItems (self, other, itmi_gold, 20);
   
   Log_SetTopicStatus (TOPIC_TalonAndre, LOG_SUCCESS);
   B_LogEntry (TOPIC_TalonAndre,"Talon bardzo się ucieszył z awansu. Za to, że powiedziałam o nim Lordowi Andre, dał mi tylko 20 sztuk złota. Chociaż... zatrzymałam cały łup bandytów.");
   AI_StopProcessInfos (self);
};

//*********************************************************************
//   Talon
//*********************************************************************
INSTANCE DIA_Andre_Talon   (C_INFO)
{
   npc         = Mil_311_Andre;
   nr          = 100;
   condition   = DIA_Andre_Talon_Condition;
   information = DIA_Andre_Talon_Info;
   permanent   = FALSE;
   description   = "Możemy porozmawiać o Talonie?";
};

FUNC INT DIA_Andre_Talon_Condition()
{
   if (Npc_Knowsinfo (other,DIA_MIL_2200_MOD_Talon_khorinis))
   {   
      return TRUE;
   };
};

FUNC VOID DIA_Andre_Talon_Info()
{
   AI_Output (other, self ,"DIA_MIL_2200_MOD_Talon_konieczadania_15_00"); //Możemy porozmawiać o Talonie?
   AI_Output (self , other,"DIA_MIL_2200_MOD_Talon_konieczadania_61_01"); //Oczywiście, o co chodzi?
   AI_Output (other, self ,"DIA_MIL_2200_MOD_Talon_konieczadania_15_02"); //Talon uratował mi życie przed wieloma bandytami.
   AI_Output (self, other ,"DIA_MIL_2200_MOD_Talon_konieczadania_61_03"); //Naprawdę? a masz na to jakiś dowód?
   AI_Output (other, self ,"DIA_MIL_2200_MOD_Talon_konieczadania_15_04"); //Ich ciała leża nadal na moście w drodze do tawerny, jeśli mi nie wieżysz możesz sprawdzić.
   AI_Output (self, other ,"DIA_MIL_2200_MOD_Talon_konieczadania_61_05"); //No dobrze, wierzę Ci. Talon jest jednak inny niż myślałem.
   AI_Output (self, other ,"DIA_MIL_2200_MOD_Talon_konieczadania_61_06"); //Jeśli możesz, poinformuj go o awansie.
   AI_Output (other, self ,"DIA_MIL_2200_MOD_Talon_konieczadania_15_07"); //Napewno się ucieszy.
   
   B_LogEntry (TOPIC_TalonAndre,"Pochwaliłam Talona, przed Andre, muszę mu przekazać, że dostaje awans.");
   AI_StopProcessInfos (self);
};

Skompiluj dialogi w Spacerze lub Redefixie. 

[Xitros]

Wlasnie to mam zrobione.

[Bogdan Zwei]

Jeśli masz Windows 7, to ciesz się, że w ogóle Gothic Ci poprawnie działa. U mnie na czyściutkim Gothic są bugi nie z tej ziemi, np. crash, gdy jest po godzinie 20, crash przy wchodzeniu do innych światów itp. Zdarzały się też crashe, gdy zbyt dużo NPC coś mówiło, zaś na Windows XP działa wszytko rewelacyjnie - nawet napchany Gothic, który nie wyrabia z FPS'ami działa poprawnie.

[SabeMiczu]

Xitro nie wiem czy tylko skompilowałeś ale musisz też aktualizować dialogi Kliknij kopertę taką jest na jednym z pasków a potem update i Save Będzie trochę długo. Jeżeli chodziło ci o to co napisałem to nie wiem dlaczego a jeżeli nie to spróbuj tak jak napisałem i w tedy efekt sprawdź.

[Xitros]

SabeMiczu.
Mam zaktualizowane dialogi, bez tego chyba by nie bylo dialogow w grze.

Bogdan Zwei.
Tak, mam Win7. Wiec co mam zrobic, zeby byly widoczne napisy ?

[chicken]

Ty, a masz może włączone napisy w ustawieniach? Z tego co pamiętam to w g1 to było, zobacz w g2.

[SabeMiczu]

W g1 Było ale wątpie g2

[Xitros]

W kazdym gothicu mam wlaczone :p
Chodzi o to, ze postacie nie mowia dialogow, nawet nie ma animacji ruszania rekoma podczas rozmowy.

EDIT:
Zrobilem nowa postac z nowymi dialogami, dialogi wkleilem na sam dol dialogu Cavalorna.
Napisy sa juz polskie, ale nadal nic nie mowi :(

Co mam robic ?

Ja dalej jestem za tym, że źle skompilowałeś te dialogi. Opisz może jak to robisz. 

[Xitros]

Robie tak:

Minuta 3:03

https://www.youtube.com/watch?v=FNvE0JFQGvw

[MajkeI]

Jak ci się załadują dialogi to zaznacz wszyskie (klikasz na górny a potem CTRL+SHIFT i na ten na samym dole) i usuwasz. Potem zaktulizuj na nowo. Bedzie każdy po jednym (bez powtórzeń).
A już najlepiej ściągnij sobie Redefixa, aktualizuje dialogi w parę sekund

[Xitros]

Nadal nic :(

Zaktualizowalem nawet redefixem, tez nic. Sprobuje zrobic paczke z modem tak jak Czip17.

EDIT
Po zrobieniu paczki z modem dialogi dzialaja
Dzieki za pomoc

[Maciej]

Dlatego ze dialogi sa w paczce Gothicmod.mod
Daj paczke np z 1 tex i problem solved.