Jak zrobić bonus po zabiciu bossa?

[paweu]

@Młody ścierwojad, zrobiłem jak napisałeś, jednak wciąż mam błąd z tym ifem (syntax error)

if (Hlp_GetInstanceID(self) == Hlp_GetInstanceID(giantbug_uniq))

Co do edytora tekstu, właśnie ściągnąłem Notepad++ i wygląda lepiej.

[Mikotsune]

Masz zrobionego nowego potwora w MST_(nazwa potwora).d ?

if (Hlp_GetInstanceID(self) == Hlp_GetInstanceID(Kod_Na_Potwora))

instance Kod_Na_Potwora(Mst_Default_Giant_Rat)
{
   B_SetVisuals_Giant_Rat();
   Npc_SetToFistMode(self);
};

[paweu]

Tak.

INSTANCE giantbug_uniq (Mst_Default_Giant_Bug)
{
   //----- Monster ----
   name                     =   "Żarłoczna polna bestia";
   level                     =   150;
   
   //----- Attribute ----
   attribute   [ATR_STRENGTH]      =   250;
   attribute   [ATR_DEXTERITY]      =   250;
   attribute   [ATR_HITPOINTS_MAX]   =   1600;
   attribute   [ATR_HITPOINTS]      =   1600;

   //----- Protections ----
   protection   [PROT_BLUNT]      =   380;
   protection   [PROT_EDGE]         =   220;
   protection   [PROT_POINT]      =   260;
   protection   [PROT_FIRE]         =   175;
   protection   [PROT_FLY]         =   150;
   protection   [PROT_MAGIC]      =   240;

   //----- Kampf-Taktik ----
   fight_tactic               = FAI_GIANT_BUG;

   //----- Visuals ----
   B_SetVisuals_Giant_Bug();
   Mdl_SetModelScale(self, 0.9, 0.9, 0.9);
   Npc_SetToFistMode(self);
};

[Mikotsune]

Masz coś namieszane. Na pewno nie jest to wina tego co podałeś - wszystko jest w porządku.

Wyślij cały ZS_Dead.d, tylko wrzuć to w spoiler.

[paweu]

Spoiler

func void ZS_Dead ()
{   
   // ------ aivars resetten ------
   self.aivar[AIV_RANSACKED] = FALSE;
   self.aivar[AIV_PARTYMEMBER] = FALSE;
   
   B_StopLookAt   (self);
   AI_StopPointAt   (self);
      
   // ------ XP ------
   if ( Npc_IsPlayer(other) || (other.aivar[AIV_PARTYMEMBER]==TRUE) )
   && (self.aivar[AIV_VictoryXPGiven] == FALSE)                     
   {
      B_GivePlayerXP (self.level * XP_PER_VICTORY);         
      
      self.aivar[AIV_VictoryXPGiven] = TRUE;
   };
   
   // ------ Greg ------
   if C_IAmCanyonRazor (self) == TRUE
   {
      CanyonRazorBodyCount = CanyonRazorBodyCount +1;
      if (MIS_Addon_Greg_ClearCanyon == LOG_RUNNING)
      {
         B_CountCanyonRazor ();
      };
   };
   
   // ------ Sumpfdrohne -------
   if (self.aivar[AIV_MM_REAL_ID] == ID_SWAMPDRONE)
   {
      if (Npc_GetDistToNpc(self, other) < 300)
      {
         other.attribute[ATR_HITPOINTS] -= 50;
         //Npc_ChangeAttribute(other, ATR_HITPOINTS, -50);
      };
   };
   
   // ------ DiegoOW ------
   if (Hlp_GetInstanceID(self) == Hlp_GetInstanceID(DiegoOW))
   {
      Diego_IsDead = TRUE;
   };
   
   if (Npc_IsPlayer(other))
   {
      self.aivar[AIV_KilledByPlayer] = TRUE;
      
      // ------ STORY ------
      
      // ------ Dunkle Seite der Macht -------
      
      if (C_DropUnconscious())
         {
            MadKillerCount = (MadKillerCount + 1);
         };      
      
      // ------ Fester------
      if (self.guild == GIL_GIANT_BUG)
      && (MIS_Fester_KillBugs == LOG_RUNNING)
      {
         Festers_Giant_Bug_Killed = Festers_Giant_Bug_Killed + 1;
      };
      // ----- Alligator Jack -----
      if Hlp_GetInstanceID (self) == Hlp_GetInstanceID (Swamprat)
      && (MIS_KrokoJagd == LOG_Running)
      {
         AlligatorJack_KrokosKilled = AlligatorJack_KrokosKilled +1;
      };
      
      
      if Hlp_GetInstanceID (self) == Hlp_GetInstanceID (Ramon)
      {
         Player_HasTalkedToBanditCamp = TRUE;
      };
      if Hlp_GetInstanceID (self) == Hlp_GetInstanceID (Franco)
      {
         if  (MIS_HlpLogan == LOG_RUNNING)
         {
            MIS_HlpLogan = LOG_OBSOLETE;
         };
         if  (MIS_HlpEdgor == LOG_RUNNING)
         {
            MIS_HlpEdgor = LOG_OBSOLETE;
         };
      };
      if Hlp_GetInstanceID (self) == Hlp_GetInstanceID (Fortuno)
      {
         Log_SetTopicStatus (Topic_Addon_Fortuno,LOG_OBSOLETE);
      };
   };
      
      //------Addon Garaz Minecrawler Höhle------egal wer tötet----
      if  Hlp_GetInstanceID (self) == Hlp_GetInstanceID (Goldminecrawler)
      {
         if (Minecrawler_Killed >= 9)
         && (Bloodwyn_Spawn == FALSE)
         {   
            AI_Teleport (Bloodwyn,"ADW_MINE_TO_MC_03");
            B_StartOtherRoutine (Bloodwyn,"MINE");
            B_GivePlayerXP (XP_Addon_Bloodwyn);
            Bloodwyn_Spawn = TRUE;
         }
         else
         {
            Minecrawler_Killed = (Minecrawler_Killed + 1);
         
         };
      };
      
   // ------ weil sonst Händler bevor man zum ersten Mal TRADE gewählt hat nix haben ------
   B_GiveTradeInv(self);//Joly:   STEHEN LASSEN!!!!!!!!!!!!!!!

   // ------ Monster-Inventory abhängig vom Spieler-Talent ------
   B_GiveDeathInv(self);
   B_ClearRuneInv(self); //klaue alle runen!!
   
   // ------ PetzCounter meiner Home-Location runtersetzen ------
   B_DeletePetzCrime (self); //hat bei CRIME_NONE (oder keiner Home-Location) keine Auswirkungen
   self.aivar[AIV_NpcSawPlayerCommit] = CRIME_NONE;
   
   // ------ Equippte Waffen können nicht genommen werden! ------
   AI_UnequipWeapons (self);
   
   self.aivar[AIV_TAPOSITION] = FALSE;
};

if (Hlp_GetInstanceID (self) == Hlp_GetInstanceID (giantbug_uniq) //tu wyskakuje błąd (linia 135)
{
   hero.LP   =   hero.LP   +   3;

   PrintScreen("Bohaterski wyczyn!",-1,50,FONT_Screen,3);
   PrintScreen("Punkty nauki +3",-1,53,FONT_Screen,3);

   Snd_Play ("MFX_HEAL_CAST");

};

func int ZS_Dead_loop ()
{
   // Drachen
   if (self.aivar[AIV_TAPOSITION] == FALSE)
   {
      B_DragonKillCounter (self);
      self.aivar[AIV_TAPOSITION] = TRUE;
   };
   
   return LOOP_CONTINUE;
};

[Bogdan Zwei]

Dodałeś swój skrypt POZA funkcją. dodaj go przed ostatnią klamrą.

[Mikotsune]

Miałeś dać w spoiler, nie cytat

Napisałem Ci:

func void ZS_Dead()
{
Wklej tutaj

[paweu]

Sorka, teraz już wiem gdzie ten spoiler

Wkleiłem to tam gdzie mówisz, a teraz wyskakuje znowu jakieś

Syntax error SELF.AIVAR (line 22)

A tu jak wygląda:

Spoiler

func void ZS_Dead ()
{
   if (Hlp_GetInstanceID (self) == Hlp_GetInstanceID (giantbug_uniq))
    {
           hero.LP   =   hero.LP   +   3;

           PrintScreen("Bohaterski wyczyn!",-1,50,FONT_Screen,3);
           PrintScreen("Punkty nauki +3",-1,53,FONT_Screen,3);

           Snd_Play ("MFX_HEAL_CAST");
       
    };
   
   // ------ aivars resetten ------
   self.aivar[AIV_RANSACKED] = FALSE;
   self.aivar[AIV_PARTYMEMBER] = FALSE;
   
   B_StopLookAt   (self);
   AI_StopPointAt   (self);
      
   // ------ XP ------
   if ( Npc_IsPlayer(other) || (other.aivar[AIV_PARTYMEMBER]==TRUE) )
   && (self.aivar[AIV_VictoryXPGiven] == FALSE)                     
   {
      B_GivePlayerXP (self.level * XP_PER_VICTORY);         
      
      self.aivar[AIV_VictoryXPGiven] = TRUE;
   };

[Mikotsune]

Edytuj tamten post i zmień na spoiler

Jeśli wyskakuję jakiś błąd, to napisz, w której to jest linijce, tak na przyszłość

Usuń WSZYSTKO z ZS_Dead.d i wklej to:

Kod: [Zaznacz]

func void ZS_Dead ()
{
if (Hlp_GetInstanceID (self) == Hlp_GetInstanceID (giantbug_uniq))
{
hero.LP   =   hero.LP   +   3;

PrintScreen("Bohaterski wyczyn!",-1,50,FONT_Screen,3);
PrintScreen("Punkty nauki +3",-1,53,FONT_Screen,3);

Snd_Play ("MFX_HEAL_CAST");
};

// ------ aivars resetten ------
self.aivar[AIV_RANSACKED] = FALSE;
self.aivar[AIV_PARTYMEMBER] = FALSE;

B_StopLookAt   (self);
AI_StopPointAt   (self);

// ------ XP ------
if (( Npc_IsPlayer(other) || (other.aivar[AIV_PARTYMEMBER]==TRUE) )
&& (self.aivar[AIV_VictoryXPGiven] == FALSE))                     
{
B_GivePlayerXP (self.level * XP_PER_VICTORY);         
     
self.aivar[AIV_VictoryXPGiven] = TRUE;
};

// ------ Greg ------
if (C_IAmCanyonRazor (self) == TRUE)
{
CanyonRazorBodyCount = CanyonRazorBodyCount +1;
if (MIS_Addon_Greg_ClearCanyon == LOG_RUNNING)
{
B_CountCanyonRazor ();
};
};

// ------ Sumpfdrohne -------
if (self.aivar[AIV_MM_REAL_ID] == ID_SWAMPDRONE)
{
if (Npc_GetDistToNpc(self, other) < 300)
{
other.attribute[ATR_HITPOINTS] -= 50;
//Npc_ChangeAttribute(other, ATR_HITPOINTS, -50);
};
};
   
// ------ DiegoOW ------
if (Hlp_GetInstanceID(self) == Hlp_GetInstanceID(DiegoOW))
{
Diego_IsDead = TRUE;
};
   
if (Npc_IsPlayer(other))
{
self.aivar[AIV_KilledByPlayer] = TRUE;
     
// ------ STORY ------
     
// ------ Dunkle Seite der Macht -------
     
if (C_DropUnconscious())
{
MadKillerCount = (MadKillerCount + 1);
};     
     
// ------ Fester------
if ((self.guild == GIL_GIANT_BUG)
&& (MIS_Fester_KillBugs == LOG_RUNNING))
{
Festers_Giant_Bug_Killed = Festers_Giant_Bug_Killed + 1;
};
// ----- Alligator Jack -----
if (Hlp_GetInstanceID (self) == Hlp_GetInstanceID (Swamprat)
&& (MIS_KrokoJagd == LOG_Running))
{
AlligatorJack_KrokosKilled = AlligatorJack_KrokosKilled +1;
};
     
     
if (Hlp_GetInstanceID (self) == Hlp_GetInstanceID (Ramon))
{
Player_HasTalkedToBanditCamp = TRUE;
};
if (Hlp_GetInstanceID (self) == Hlp_GetInstanceID (Franco))
{
if  (MIS_HlpLogan == LOG_RUNNING)
{
MIS_HlpLogan = LOG_OBSOLETE;
};
if  (MIS_HlpEdgor == LOG_RUNNING)
{
MIS_HlpEdgor = LOG_OBSOLETE;
};
};
if (Hlp_GetInstanceID (self) == Hlp_GetInstanceID (Fortuno))
{
Log_SetTopicStatus (Topic_Addon_Fortuno,LOG_OBSOLETE);
};
};
     
//------Addon Garaz Minecrawler Höhle------egal wer tötet----
if  (Hlp_GetInstanceID (self) == Hlp_GetInstanceID (Goldminecrawler))
{
if ((Minecrawler_Killed >= 9)
&& (Bloodwyn_Spawn == FALSE))
{   
AI_Teleport (Bloodwyn,"ADW_MINE_TO_MC_03");
B_StartOtherRoutine (Bloodwyn,"MINE");
B_GivePlayerXP (XP_Addon_Bloodwyn);
Bloodwyn_Spawn = TRUE;
}
else
{
Minecrawler_Killed = (Minecrawler_Killed + 1);
         
};
};
     
// ------ weil sonst Händler bevor man zum ersten Mal TRADE gewählt hat nix haben ------
B_GiveTradeInv(self);//Joly:   STEHEN LASSEN!!!!!!!!!!!!!!!

// ------ Monster-Inventory abhängig vom Spieler-Talent ------
B_GiveDeathInv(self);
B_ClearRuneInv(self); //klaue alle runen!!
   
// ------ PetzCounter meiner Home-Location runtersetzen ------
B_DeletePetzCrime (self); //hat bei CRIME_NONE (oder keiner Home-Location) keine Auswirkungen
self.aivar[AIV_NpcSawPlayerCommit] = CRIME_NONE;
   
// ------ Equippte Waffen können nicht genommen werden! ------
AI_UnequipWeapons (self);
   
self.aivar[AIV_TAPOSITION] = FALSE;
};

func int ZS_Dead_loop ()
{
// Drachen
if (self.aivar[AIV_TAPOSITION] == FALSE)
{
B_DragonKillCounter (self);
self.aivar[AIV_TAPOSITION] = TRUE;
};
   
return LOOP_CONTINUE;
};

[paweu]

Usunięte, i wklejone tak jak podałeś, ale mam niestety kolejny błądzik:

Spoiler

Missing ")" (line 11)

[Mikotsune]

Edytowałem post. Jeszcze raz usuń wszystko i wklej.

[paweu]

Dobra, myślę że skrypt z potworem i PN chyba działa, aczkolwiek nie jestem pewien ponieważ mam taki błąd, tym razem w skrypcie nauki za złoto w dialogu Cavalorna.

Spoiler

Unknown identifier: FUNC (line 1078)

A tu jak wygląda:

Spoiler

FUNC VOID DIA_Addon_Cavalorn_Teach_BOW_1 ()
{
   if B_GiveInvItems (other, self, ItmI_Gold, 150)
   {
   B_TeachFightTalentPercent (self, other, NPC_TALENT_BOW, 1, 90);
   
   DIA_Addon_Cavalorn_TEACH_Choices ();
};

[Siemekk]

Weź poczytaj o błędach i identyfikatorach parsera, a nie będziesz tu pisał każdy brakujący średnik...

[paweu]

Skrypt "bossa" działa. Co prawda teksty się na siebie nakładają, ale ważne że działa xD

https://zapodaj.net/f900f2c1cb886.jpg.html


Propsik dla Ciebie, @Młody ścierwojad, dziękuję

[Kempix]

Skrypt "bossa" działa. Co prawda teksty się na siebie nakładają, ale ważne że działa xD

Wystarczy, że zmienisz pozycję na jednym z printów.

[Mikotsune]

Możesz pobawić się liczbami +/- i czcionką.
Spróbuj tak:

PrintScreen("Bohaterski wyczyn!",-1,47,FONT_Screen,3);
PrintScreen("Punkty nauki +3",-1,53,FONT_ScreenSmall,3);

Spoiler

Naucz się najpierw podstaw i zrób normalnego nauczyciela, a dopiero potem zacznij go przerabiać.

Zobacz poradniki na youtube - czip17 lub wejdź w tutoriale.
Otwórz dialog jakiegoś nauczyciela i zobacz jak to jest zrobione.

Nauczysz się wszystkiego otwierając pliki i patrząc co i jak jest zrobione. Te początki modowania

Pewnie nikt by Ci nie pomógł z tak prostą rzeczą (ZS_Dead.d) i raczej nie doczekałbyś się odpowiedzi...

Pamiętaj, rób na spokojnie i powoli.
Powodzenia!

[paweu]

Tak, masz rację, jestem w tym początkujący, ale mam chęci żeby się rozwinąć, a przecież forum jest po to, żeby zadawać tu pytania nawet o najmniejszy szczegół

Można zamknąć temat, problem może nie został rozwiązany w 100%, lecz bardziej mi zależało na skrypcie "bossa". Pozdrawiam