Expected "{"

[DizZy]

Witam.Mam pewien problem podzczas parsownia skryptów wykrywa mi błąd w tej części dialogu "expected {"

FUNC INT DIA_PAL_888_Madris_mamwode_Condition()
{
if (npc_knowsinfo (other, DIA_PAL_888_Madris_zadanie))
&& (npc_hasitems (other, itfo_water) >= 1);
{

   return TRUE;
};
};

Dokładniej w tej linijce:

&& (npc_hasitems (other, itfo_water) >= 1);

Cały dialog tutaj :

//*********************************************************************
//   Info EXIT
//*********************************************************************
INSTANCE DIA_PAL_888_Madris_EXIT   (C_INFO)
{
   npc         = PAL_888_Madris;
   nr          = 999;
   condition   = DIA_PAL_888_Madris_EXIT_Condition;
   information = DIA_PAL_888_Madris_EXIT_Info;
   permanent   = TRUE;
   description = DIALOG_ENDE;
};

FUNC INT DIA_PAL_888_Madris_EXIT_Condition()
{
   return TRUE;
};

FUNC VOID DIA_PAL_888_Madris_EXIT_Info()
{
   AI_StopProcessInfos (self);
};

//*********************************************************************
//   Info Hello
//*********************************************************************
INSTANCE DIA_PAL_888_Madris_witaj   (C_INFO)
{
   npc         = PAL_888_Madris;
   nr          = 1;
   condition   = DIA_PAL_888_Madris_witaj_Condition;
   information = DIA_PAL_888_Madris_witaj_Info;
   permanent   = FALSE;
   description = "Witaj , kim jesteś?";
};

FUNC INT DIA_PAL_888_Madris_witaj_Condition()
{
   return TRUE;
};

FUNC VOID DIA_PAL_888_Madris_witaj_Info()
{
   AI_Output (other ,self ,"DIA_PAL_888_Madris_witaj_15_00"); //Witaj , kim jesteś ?
   AI_Output (self ,other,"DIA_PAL_888_Madris_witaj_01_01"); //Jestem paladynem , nazywam się Madris.Stoje tu i patroluje czy orkowie nie nadciągają.
   AI_Output (self ,other,"DIA_PAL_888_Madris_witaj_01_02"); //Strasznie chce mi się pić a nie moge się stąd ruszyć.
   
};

//*********************************************************************
//   ZADANIE
//*********************************************************************
INSTANCE DIA_PAL_888_Madris_zadanie   (C_INFO)
{
   npc         = PAL_888_Madris;
   nr          = 1;
   condition   = DIA_PAL_888_Madris_zadanie_Condition;
   information = DIA_PAL_888_Madris_zadanie_Info;
   permanent   = FALSE;
   description = "Może moge ci pomóc...?";
};

FUNC INT DIA_PAL_888_Madris_zadanie_Condition()

{
if (npc_knowsinfo (other, DIA_PAL_888_Madris_witaj))
{

   return TRUE;
};
};

FUNC VOID DIA_PAL_888_Madris_zadanie_Info()
{
   AI_Output (other ,self ,"DIA_PAL_888_Madris_zadanie_15_00"); //Może moge ci pomóc ?
   AI_Output (self ,other,"DIA_PAL_888_Madris_zadanie_01_01"); //Jasne możesz przynieść mi wode.
   AI_Output (other ,self ,"DIA_PAL_888_Madris_zadanie_01_02"); //Pewnie postaram się to szybko załatwić.
   
   Log_CreateTopic (TOPIC_woda, LOG_MISSION);
   Log_SetTopicStatus (TOPIC_woda, LOG_RUNNING);
   B_LogEntry (TOPIC_woda, "Paladyn Madris poprosił mnie abym przyniósł mu wody");
   
};

//*********************************************************************
//   KONIEC ZADANIA
//*********************************************************************
INSTANCE DIA_PAL_888_Madris_mamwode   (C_INFO)
{
   npc         = PAL_888_Madris;
   nr          = 1;
   condition   = DIA_PAL_888_Madris_mamwode_Condition;
   information = DIA_PAL_888_Madris_mamwode_Info;
   permanent   = FALSE;
   description = "Mam wodę";
};

FUNC INT DIA_PAL_888_Madris_mamwode_Condition()
{
if (npc_knowsinfo (other, DIA_PAL_888_Madris_zadanie))
&& (npc_hasitems (other, itfo_water) >= 1);
{

   return TRUE;
};
};

FUNC VOID DIA_PAL_888_Madris_mamwode_Info()  //&& (npc_hasitems (other, itfo_water) >= 1);
{
   AI_Output (other ,self ,"DIA_PAL_888_Madris_mamwode_15_00"); //Mam wodę.
   AI_Output (self ,other,"DIA_PAL_888_Madris_mamwode_01_01"); //Dzięki masz tutaj nagrodę.
   AI_Output (other ,self ,"DIA_PAL_888_Madris_mamwode_01_02"); //Nie ma za co.
   
   B_Giveinvitems (other, self, itfo_water, 1);
   Createinvitems (self, itmi_gold, 100);
   B_giveinvitems (self, other, itmi_gold, 100);
   Log_SetTopicStatus (TOPIC_woda, LOG_SUCCES);
   B_LogEntry (TOPIC_woda, "Dałem Madrisowi wode");
   
};

Niewiem w czym jest problem ;c

[Remix]

Usuń ";" po tej linijce i będzie git ;)

[Drock]

Ponieważ w tej linijce

Kod: [Zaznacz]

&& (npc_hasitems (other, itfo_water) >= 1);
nie powinno być " ; ".

 i dobra rada używaj tabulatora poprawi czytelność kodu.

Kod: [Zaznacz]

FUNC INT DIA_PAL_888_Madris_mamwode_Condition()
{
if (npc_knowsinfo (other, DIA_PAL_888_Madris_zadanie))
&& (npc_hasitems (other, itfo_water) >= 1)
{

return TRUE;
};
};


[DizZy]

Wielkie dzięki , leci propsik.

[RafalBudzis]

i dobra rada używaj tabulatora poprawi czytelność kodu.

Kod: [Zaznacz]

FUNC INT DIA_PAL_888_Madris_mamwode_Condition()
{
if (npc_knowsinfo (other, DIA_PAL_888_Madris_zadanie))
&& (npc_hasitems (other, itfo_water) >= 1)
{

return TRUE;
};
};


i lepiej używaj ich w taki sposób

Kod: [Zaznacz]

FUNC INT DIA_PAL_888_Madris_mamwode_Condition()
{
if (npc_knowsinfo (other, DIA_PAL_888_Madris_zadanie))
&& (npc_hasitems (other, itfo_water) >= 1)
{
return TRUE;
};
};

zasada jest prosta jeden

Kod: [Zaznacz]

{ od następnej linijki jeden tab więcej jeden

Kod: [Zaznacz]

}; tab mniej w linijce występowania



do tego wszystkie wartosci INT`a oprócz 0 interpretowane są jako prawda wiec zamiast

Kod: [Zaznacz]

(npc_hasitems (other, itfo_water) >= 1)
mozna by napisać

Kod: [Zaznacz]

npc_hasitems (other, itfo_water)