func int C_OtherIsToleratedEnemy(var C_NPC slf, var C_NPC oth)
{
   PrintDebugNpc         (PD_ZS_DETAIL,   "C_OtherIsToleratedEnemy");

   //-------- Orkverfolger --------
   if (C_NpcIsOrc(slf))
   {
      PrintDebugNpc      (PD_ZS_DETAIL,   "...'self' ist Ork!");

      //---- Ulu-Mulu in der Hand ? ----
      var C_ITEM         weapon;
      var int            weaponInstance;
      weapon =          Npc_GetReadiedWeapon(oth);
      if (Hlp_IsValidItem(weapon))
      {
         weaponInstance =Hlp_GetInstanceID(weapon);
         PrintDebugString(PD_ZS_DETAIL, "...gezogene Waffe von 'other': ", weapon.name);
         if (weaponInstance == UluMulu)
         {
            PrintDebugNpc(PD_ZS_DETAIL, "...true!");
            return      TRUE;
         };
      };
      
      //---- Ulu-Mulu equipped ? ----
      weapon =          Npc_GetEquippedMeleeWeapon   (oth);
      if (Hlp_IsValidItem(weapon))
      {
         weaponInstance =Hlp_GetInstanceID(weapon);
         PrintDebugString(PD_ZS_DETAIL, "...equippte Waffe von 'other': ", weapon.name);
         if (weaponInstance == UluMulu)
         {
            PrintDebugNpc(PD_ZS_DETAIL, "...true!");
            return      TRUE;
         };
      };
   };

   PrintDebugNpc         (PD_ZS_DETAIL, "...false!");
   return                FALSE;
};

func void B_TolerateEnemy(var C_NPC slf, var C_NPC oth)
{
   PrintDebugNpc         (PD_ZS_DETAIL,   "B_TolerateEnemy");

   //-------- Orkverfolger --------
   if   (C_NpcIsOrc(slf))
   &&   (Npc_GetDistToNpc(slf,oth) > HAI_DIST_ASSESSTOLERATEDENEMY)
   {
      PrintDebugNpc      (PD_ZS_DETAIL,   "...'self' ist Ork und nah genug dran!");

      var int            npcInstance;
      npcInstance =      Hlp_GetInstanceID(slf);

      //-------- Aufreger --------
      if   (npcInstance == OrcScout)
      ||   (npcInstance == OrcWarrior1)
      ||   (npcInstance == OrcWarrior2)
      {
         PrintDebugNpc   (PD_ZS_DETAIL,   "...'self' ist anderer Ork!");
         if   !Npc_IsInState(slf, ZS_Upset)
         {
            PrintDebugNpc   (PD_ZS_DETAIL,   "...'self' noch nicht in ZS_FollowPC");
            Npc_ClearAIQueue(slf);
            AI_StandUp      (slf);
            AI_StartState   (slf, ZS_Upset, 1, "");         
         };
      }

      //-------- Verfolger --------
      else if   (npcInstance == OrcWarrior3)      
      {
         PrintDebugNpc   (PD_ZS_DETAIL,   "...'self' ist Ork Tempelkrieger!");
         if   !Npc_IsInState(slf, ZS_FollowPC)
         {
            PrintDebugNpc   (PD_ZS_DETAIL,   "...'self' noch nicht in ZS_FollowPC");
            Npc_ClearAIQueue(slf);
            AI_StandUp      (slf);
            AI_StartState   (slf, ZS_FollowPC, 1, "");         
         };
      };
   };
};