Jak chcesz to sprawdź dialogi torreza z G1 lub Xardasa tam na pewno powinieneś znaleźć odpowiedź
Spoiler
instance DIA_Torrez_Belohnung (C_INFO)
{
npc = KDF_405_Torrez;
nr = 5;
condition = DIA_Torrez_Belohnung_Condition;
information = DIA_Torrez_Belohnung_Info;
permanent = 0;
description = "Przyniosłem mu list z zewnątrz i mam sobie wybrać nagrodę.";
};
FUNC int DIA_Torrez_Belohnung_Condition()
{
if ( (Npc_KnowsInfo(hero,DIA_Milten_ComesBack)) && (milten_HasLetter==TRUE) )
{
return 1;
};
};
FUNC VOID DIA_Torrez_Belohnung_Info()
{
AI_Output (other, self,"DIA_Torrez_Belohnung_15_00"); //Przysyła mnie Corristo. Przyniosłem mu list z zewnątrz i mam sobie wybrać nagrodę.
AI_Output (self, other,"DIA_Torrez_Belohnung_04_01"); //Wyświadczyłeś nam wielką przysługę i otrzymasz każdą nagrodę, jakiej zażądasz.
Info_ClearChoices (DIA_Torrez_Belohnung);
Info_AddChoice (DIA_Torrez_Belohnung,"Chciałbym dostać ten napój!(Max Mana +5)" ,DIA_Torrez_Belohnung_ManaMax);
Info_AddChoice (DIA_Torrez_Belohnung,"3 zwoje, (Kula Ognia, Piorun Kulisty i Przemiana w Ścierwojada)" ,DIA_Torrez_Belohnung_Scrolls);
Info_AddChoice (DIA_Torrez_Belohnung,"Wezmę pierścień zwinności (+5)." ,DIA_Torrez_Belohnung_Dex);
Info_AddChoice (DIA_Torrez_Belohnung,"Wezmę ten pierścień siły (+5)." ,DIA_Torrez_Belohnung_Str);
};
func void DIA_Torrez_Belohnung_Str()
{
AI_Output (other, self,"DIA_Torrez_Belohnung_Str_15_00"); //Wezmę ten pierścień siły.
AI_Output (self, other,"DIA_Torrez_Belohnung_Str_04_01"); //Tak jak się spodziewałem. Proszę, oto on.
CreateInvItem(self, Staerkering);
B_GiveInvItems (self, hero, Staerkering, 1);
Info_ClearChoices (DIA_Torrez_Belohnung);
};
func void DIA_Torrez_Belohnung_Dex()
{
AI_Output (other, self,"DIA_Torrez_Belohnung_Dex_15_00"); //Wezmę pierścień zwinności.
AI_Output (self, other,"DIA_Torrez_Belohnung_Dex_04_01"); //Zwinność zawsze powinna iść przed siłą. To był mądry wybór.
CreateInvItem(self, Ring_des_Geschicks);
B_GiveInvItems (self, hero, Ring_des_Geschicks, 1);
Info_ClearChoices (DIA_Torrez_Belohnung);
};
func void DIA_Torrez_Belohnung_Scrolls()
{
AI_Output (other, self,"DIA_Torrez_Belohnung_Scrolls_15_00"); //Wezmę te zwoje z zaklęciami.
AI_Output (self, other,"DIA_Torrez_Belohnung_Scrolls_04_01"); //Wykorzystaj je mądrze! Każdego z nich możesz użyć tylko raz!
CreateInvItems(self, ItArScrollFireball, 3);
B_GiveInvItems (self, hero, ItArScrollFireball, 3);//Wegen Bildschirmausgabe, wird direkt angepasst
Npc_RemoveInvItems(other, ItArScrollFireball, 2);
CreateInvItem(other, ItArScrollTrfScavenger);
CreateInvItem(other, ItArScrollChainLightning);
Info_ClearChoices (DIA_Torrez_Belohnung);
};
func void DIA_Torrez_Belohnung_ManaMax()
{
AI_Output (other, self,"DIA_Torrez_Belohnung_ManaMax_15_00"); //Chciałbym dostać ten napój!
AI_Output (self, other,"DIA_Torrez_Belohnung_ManaMax_04_01"); //Mądra decyzja! To najcenniejszy z przedmiotów, które mogłeś wybrać. Wypij ten napój, a twoja siła znacznie wrośnie!
CreateInvItem(self, ItFo_Potion_Mana_Perma_01);
B_GiveInvItems (self, hero, ItFo_Potion_Mana_Perma_01, 1);
Info_ClearChoices (DIA_Torrez_Belohnung);
};