Dokładnie, jeśli chodzi o G2 to pierwsze co mi przyszło do głowy to właśnie dialog z Lobartem. Konkretnie ta część:
instance DIA_Lobart_WorkNOW (C_INFO)
{
npc = BAU_950_Lobart;
nr = 1;
condition = DIA_Lobart_WorkNOW_Condition;
information = DIA_Lobart_WorkNOW_Info;
permanent = FALSE;
description = "Szukam pracy.";
};
func int DIA_Lobart_WorkNOW_Condition ()
{
if (Npc_KnowsInfo(other, DIA_Lobart_AufstandInfo))
|| (Npc_KnowsInfo(other, DIA_Lobart_STOLENCLOTHS))
|| (Npc_KnowsInfo(other, DIA_Lobart_Kleidung))
{
if (Kapitel < 3)
{
return TRUE;
};
};
};
func void DIA_Lobart_WorkNOW_Info ()
{
AI_Output (other, self, "DIA_Lobart_WorkNOW_15_00"); //Szukam pracy.
AI_Output (self, other, "DIA_Lobart_WorkNOW_05_01"); //Jeśli chcesz, możesz u mnie pracować.
AI_Output (self, other, "DIA_Lobart_WorkNOW_05_02"); //Możesz pracować w polu albo znaleźć sobie jakieś inne zajęcie. Roboty na farmie nigdy nie brakuje.
if (hero.guild == GIL_NONE)
{
AI_Output (self, other, "DIA_Lobart_WorkNOW_05_03"); //Mogę ci zapłacić, albo - jeśli wolisz - dostaniesz ode mnie porządne ubranie.
AI_Output (self, other, "DIA_Lobart_WorkNOW_05_04"); //Te rzeczy są trochę warte. Nie mogę ci ich tak po prostu oddać. Jednak jeśli zgodzisz się dla mnie pracować, sprzedam ci je po niższej cenie.
Log_CreateTopic (TOPIC_Kleidung,LOG_MISSION);
Log_SetTopicStatus (TOPIC_Kleidung,LOG_RUNNING);
B_LogEntry (TOPIC_Kleidung,"Farmer Lobart chce mi sprzedać ubranie robocze, którego część ceny mogę odpracować w polu. Im więcej pracy wykonam, tym niższa będzie cena ubrań.");
if (Npc_HasEquippedArmor(other) == FALSE)
|| (Lobart_Kleidung_Verkauft == TRUE)
{
AI_Output (self, other, "DIA_Lobart_WorkNOW_05_05"); //Na twoim miejscu wziąłbym ubranie...
}
else
{
AI_Output (self, other, "DIA_Lobart_WorkNOW_05_06"); //Ale ponieważ masz już całkiem przyzwoite ubranie, pewnie wolałbyś złoto.
};
};
AI_Output (self, other, "DIA_Lobart_WorkNOW_05_07"); //Trzeba zebrać rzepę z tego małego poletka przy stodole.
Info_ClearChoices (DIA_Lobart_WorkNOW);
Info_AddChoice (DIA_Lobart_WorkNOW, "Mam wyrywać rzepę? Chyba sobie ze mnie żartujesz!", DIA_Lobart_WorkNOW_WannaFoolMe );
Info_AddChoice (DIA_Lobart_WorkNOW, "W porządku...", DIA_Lobart_WorkNOW_Ok );
};
func void DIA_Lobart_WorkNOW_Ok()
{
AI_Output (other, self, "DIA_Lobart_WorkNOW_Ok_15_00"); //Dobrze...
if (hero.guild == GIL_NONE)
{
AI_Output (self, other, "DIA_Lobart_WorkNOW_Ok_05_01"); //Więc pośpiesz się, zanim zmienię zdanie.
};
Log_CreateTopic (TOPIC_Rueben,LOG_MISSION);
Log_SetTopicStatus (TOPIC_Rueben,LOG_RUNNING);
B_LogEntry (TOPIC_Rueben,"Farmer Lobart chce, abym zebrał z pola rzepę. W zamian oferuje mi złoto albo obniżenie ceny ubrań.");
MIS_Lobart_Rueben = LOG_RUNNING;
Info_ClearChoices (DIA_Lobart_WorkNOW);
};
func void DIA_Lobart_WorkNOW_WannaFoolMe()
{
AI_Output (other, self, "DIA_Lobart_WorkNOW_WannaFoolMe_15_00"); //Mam wyrywać rzepę? Chyba sobie ze mnie żartujesz!
AI_Output (self, other, "DIA_Lobart_WorkNOW_WannaFoolMe_05_01"); //Tak, taki dżentelmen jak ty pewnie brzydzi się uczciwą pracą, co?
if (hero.guild == GIL_NONE)
{
AI_Output (self, other, "DIA_Lobart_WorkNOW_WannaFoolMe_05_02"); //Jazda na pole albo wynoś się z mojej farmy!
}
else
{
AI_Output (self, other, "DIA_Lobart_WorkNOW_WannaFoolMe_05_03"); //W tej chwili nie mam dla ciebie żadnej innej pracy.
};
Log_CreateTopic (TOPIC_Rueben,LOG_MISSION);
Log_SetTopicStatus (TOPIC_Rueben,LOG_RUNNING);
B_LogEntry (TOPIC_Rueben,"Farmer Lobart chce, abym zebrał z pola rzepę. W zamian oferuje mi złoto albo obniżenie ceny ubrań.");
MIS_Lobart_Rueben = LOG_RUNNING;
Info_ClearChoices (DIA_Lobart_WorkNOW);
};